<%
'-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#
' Loja Exemplo Locaweb
' Versão: 6.4
' Data: 12/09/06
' Arquivo: ADM_altera_usuario_admin.asp
' Versão do arquivo: 0.0
' Data da ultima atualização: 12/03/2008
'
'-----------------------------------------------------------------------------
' Licença Código Livre: http://comercio.Locaweb.com.br/gpl/gpl.txt
'-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#

' Esta página só pode ser acessada se o visitante já se autenticou
checa_senha()

'Verifica se o perfil de usuário permite acesso a esta página
If Session("usuario_admin") <> Request("usuario") And checa_perfil_admin_menu(""&ADMGeral&"") = false Then
    Response.redirect "ADM_home.asp?msg=SEU PERFIL DE USUÁRIO NÃO PERMITE ACESSO A ESTA PÁGINA"
    Response.end
End If
%>
<!--#INCLUDE FILE="funcoes/ADM_funcoes_pedidos.asp"-->
<!--#INCLUDE FILE="../funcoes/funcoes_mail.asp"-->
<!--#INCLUDE FILE="../funcoes/funcoes.asp"-->
<!--#INCLUDE FILE="funcoes/ADM_funcoes_checa_senha.asp"-->
<%
Call abre_conexao(conexao)

    ' Associa os dados recebidos as respectivas variaveis
    nome_usuario = Request.form("nome_usuario")
    usuario = Request.form("usuario")
    email_usuario = Request.form("email_usuario")
    ddd_usuario = Request.form("ddd_usuario")
    fone_usuario = Request.form("fone_usuario")

    If Request.form("perfil_admin") <> "" Then
        perfil_usuario = Replace(Request.form("perfil_admin")," ","")
    Else
        perfil_usuario = Replace(Request.form("perfil_usuario")," ","")
    End If                    

    ' Remove usuario do banco de dados
    If Request.form("remover") = "Apagar usuário" Then
        If CheckUnicoAdminLoja(conexao,usuario) Then
            msg_resultado = "Esse usuário não pode ser apagado por ser o único com perfil de Administrador."
            Response.redirect "ADM_mostra_usuario_admin.asp?user_id_admin="&usuario&"&msg_resultado="&msg_resultado
        Else
            Conexao.Execute "DELETE FROM Usuarios_admin WHERE user_id_admin = '" & usuario &"'"
            msg_resultado = "Usuário excluido com sucesso."
            Response.redirect "adm_lista_usuario_admin.asp?msg_resultado="&msg_resultado
        End If
    End If

    If request.form("acao_admin") = "novo registro" Then
        If VerificaExistenciaDado("user_id_admin","Usuarios_admin","user_id_admin","'"&Request.form("usuario")&"'") Then
            msg_resultado = "O Usuário informado já existe cadastrado, veja os dados abaixo."
            Response.redirect "ADM_mostra_usuario_admin.asp?user_id_admin="&request("usuario")&"&msg_resultado="&msg_resultado
        End if
    End If
    
    If request.form("nova_senha") <> "" Then
        senhacadastrada = Encriptor(Pega_DadoBanco("Usuarios_admin","chave_admin","user_id_admin","'"&Request.form("usuario")&"'"),"decriptar")
        If senhacadastrada <> Request.form("senha_atual") Then
            msg_resultado = "A senha informada como atual não está correta. Senha não alterada."
            Response.redirect "ADM_mostra_usuario_admin.asp?user_id_admin="&request("usuario")&"&msg_resultado="&msg_resultado
        End if
    End if

    Set RS_UsuariosAdmin = Server.CreateObject("ADODB.Recordset")
    RS_UsuariosAdmin.CursorLocation = 3
    RS_UsuariosAdmin.CursorType = 0
    RS_UsuariosAdmin.LockType = 3
    RS_UsuariosAdmin.Open "SELECT user_id_admin, nome_usuario, email_usuario, ddd_usuario, fone_usuario, chave_admin, perfil_usuario, status FROM Usuarios_admin WHERE user_id_admin = '" & usuario & "'"  , Conexao

        If RS_UsuariosAdmin.EOF Then

                RS_UsuariosAdmin.AddNew	
                RS_UsuariosAdmin("user_id_admin") = usuario
                RS_UsuariosAdmin("status") = "2"

                pwd_usuarioBase = GerarChave(6)
                pwd_usuario = Encriptor(pwd_usuarioBase,"encriptar")

                msg_resultado = "Usuário inserido com sucesso. Foi enviado um e-mail com instruções."
        Else

            If request.form("acao_admin") = "reenvia registro" Then
                pwd_usuarioBase = Encriptor(Pega_DadoBanco("Usuarios_admin","chave_admin","user_id_admin","'"&Request.form("usuario")&"'"),"decriptar")
                msg_resultado = "Dados de acesso enviado."
            End If
            If request.form("nova_senha") <> "" Then
                msg_resultado = "Senha alterada com sucesso."
                pwd_usuario = Encriptor(Request.Form("nova_senha"),"encriptar")
            End If

        End If

        RS_UsuariosAdmin("nome_usuario") = nome_usuario
        RS_UsuariosAdmin("email_usuario") = email_usuario
        RS_UsuariosAdmin("ddd_usuario") = ddd_usuario
        RS_UsuariosAdmin("fone_usuario") = fone_usuario
        If pwd_usuario <> "" Then
            RS_UsuariosAdmin("chave_admin") = pwd_usuario
        End If
        If checa_perfil_admin_menu(""&ADMGeral&"") Then
            If request.form("acao_admin") = "novo registro" Then
                RS_UsuariosAdmin("perfil_usuario") = perfil_usuario
            Else
                If CheckUnicoAdminLoja(conexao,usuario) And RS_UsuariosAdmin("perfil_usuario") <> perfil_usuario Then
                    msg_resultado = "Dados alterados com sucesso. O perfil desse usuário não pode ser modificado por ser o único Administrador da loja."
                Else
                    RS_UsuariosAdmin("perfil_usuario") = perfil_usuario
                End If
            End If
        End If
        If request.form("bloquear") <> "" Then
            RS_UsuariosAdmin("status") = request.form("bloquear")
        End If

    If msg_resultado = "" Then
        msg_resultado = "Dados alterados com sucesso"
    End if

    RS_UsuariosAdmin.Update

    If request.form("acao_admin") = "novo registro" Or request.form("acao_admin") = "reenvia registro" Then

        Titulo = "Notificação Importante - " & Application("NomeLoja")
       
        message = "Prezado(a) " & nome_usuario & "," & Chr(13) & Chr(10) & Chr(13) & Chr(10)
        
        If RS_UsuariosAdmin("status") = "2" Then
            message = message & "Você foi cadastrado como: " & Decodifica_Perfil(perfil_usuario) & "; da loja " & Application("NomeLoja") & ". Para ter acesso às funcionalidades administrativas de seu usuário será necessário desbloquear a senha, segue abaixo dados de acesso: "& Chr(13) & Chr(10) & Chr(13) & Chr(10)
        Else
            message = message & "Você está cadastrado como: " & Decodifica_Perfil(perfil_usuario) & "; da loja " & Application("NomeLoja") & ". Segue abaixo dados de acesso: "& Chr(13) & Chr(10) & Chr(13) & Chr(10)
        End If
        
        message = message & "Usuário: " & usuario & Chr(13) & Chr(10)
        message = message & "Senha: " & pwd_usuarioBase & Chr(13) & Chr(10) 
        message = message & "Endereço: " & Application("URLloja") & "/painelctrl" & Chr(13) & Chr(10) 
        
        If RS_UsuariosAdmin("status") = "2" Then
            message = message & "OBS.: É obrigatório alterar a senha." & Chr(13) & Chr(10)
        End If

        message = message & Chr(13) & Chr(10)
        message = message & "Atenciosamente," & Chr(13) & Chr(10)
        message = message & "Administrador"

        Call funcao_mail(Titulo, email_usuario, message, 0)

    End if
    Response.redirect "ADM_mostra_usuario_admin.asp?user_id_admin=" & usuario & "&msg_resultado=" & msg_resultado

    Set RS_UsuariosAdmin = Nothing
%>